COMMENT ⊗   VALID 00005 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	TITLE CAMDRV
C00004 00003	CHGIT:	SPCWAR 1,GO
C00005 00004	SW6:	TRNN 4,2↔DISMIS
C00010 00005	--------------------------------------------------------------------
C00013 ENDMK
C⊗;
TITLE CAMDRV
	P←17
	OPDEF GO[JRST]
SA:	OUTSTR [ASCIZ/
TURN POTS TO CENTER OF RANGE,
TYPE <CR> WHEN READY./]
	INCHRW↔CAIE 15↔JRST SA↔INCHRW
	MOVE P,[XWD 10,PDL]↔SETZM FLAG
STRT:	SPCWAR SW6
AROUND:	MOVEI↔SLEEP
	SKIPN FLAG↔JRST .-2
	SPCWAR 636367
	SKIPN DRIVE↔GO STRT
CHGIT:	SPCWAR 1,GO
	MOVEI↔SLEEP
	SKIPE DRIVE↔JRST CHGIT+1
	SPCWAR 636367
	MOVEI 5,6
	MOVE 7,[POINT 12,AD14]
	TTYUUO 3,[ASCIZ/REF	PAN	TILT	FOCUS	ZOOM	IRIS
/]
DOIT:	ILDB 14,7↔TRC 14,4000↔IDIVI 14,=1000↔ADDI 14,60↔TTYUUO 1,14
	MOVE 14,15↔IDIVI 14,=100↔ADDI 14,60↔TTYUUO 1,14
	MOVE 14,15↔IDIVI 14,=10↔ADDI 14,60↔TTYUUO 1,14
	ADDI 15,60↔TTYUUO 1,15
	TTYUUO 3,[ASCIZ/	/]
	SOJG 5,DOIT
	TTYUUO 3,[ASCIZ/
/]
	JRST STRT
SW6:	TRNN 4,2↔DISMIS
	MOVE 17,[XWD 10,PDL6]
	MOVEI 6,122000		;AD CHANNEL-12, AUTO INCREMENT MODE.
	PUSHJ P,FIND
	MOVE 10,[POINT 12,AD14]
	MOVE 13,[POINT 7,DRIVE]
	MOVEI 14,3
SPEED:	ILDB 10↔LSH -5		;CONVERT 12-BYTE FROM A/D INTO 7 BIT BYTE.
	CAILE 20↔CAIL 160↔SETZ↔IDPB 13
	SOJGE 14,SPEED
	DATAO 410,DRIVE
	MOVEI 6,772000		;A/D CHANNEL 77 AUTO INCREMENT.
	PUSHJ P,FIND
	SETOM FLAG
	DISMIS
;--------------------------------------------------------------------
FIND:	CONI 204,CHAN		;GRAB 136
	SETZM FLAG
	CONO 204,4250		;START 136.
	CONO 424,@6		;A/D
	MOVE 5,[-2,,0]
AD11:	MOVEI 3,10
	MOVEI 4,25
	CONI 204,1
	TRNE 1,11000
	JRST AD12
	SOJN 4,.-3
	JRST HUNG
AD12:	TRNE 1,10000
	JRST DAMIT
AD13:	DATAI 204,AD14(5)
	AOBJN 5,AD11
	CONO 424,4000		;STOP A/D
	CONO 204,@CHAN		;RESTORE 136.
	POPJ P,
;--------------------------------------------------------------------
DRIVE:	0
PDL:	BLOCK 10
PDL6:	BLOCK 10
AD14:	BLOCK 2
CHAN:	0
FLAG:	0
HANGED:	0
DAMNED:	0	;DATA MISSED.
;--------------------------------------------------------------------
HUNG:	SETOM HANGED↔SETOM FLAG↔DISMIS
DAMIT:	SETOM DAMNED↔SETOM FLAG↔DISMIS
END SA